tcshの設定

はじめに

ここにはtcshの設定に関することを書いておきます。

~/.login

こんな感じです。

### .login

[ -x /usr/games/fortune ] && /usr/games/forture

# ^S doesn't stop output to terminal.
stty stop undef

umask 022

# Path Setting.
set path = (${HOME}/local/bin ${HOME}/local/X11R6/bin \
            /bin /usr/local/bin /usr/bin \
            /usr/local/X11R6/bin /usr/X11R6/bin \
            /usr/local/games /usr/games)

setenv RUBYLIB ".:${HOME}/local/lib/ruby"

setenv LANG ja_JP.eucJP
setenv XMODIFIERS "@im=kinput2"

# For gdb
setenv CFLAGS "-g"

# For w3m
setenv HTTP_HOME http://www.google.co.jp/

# For man on the Emacs
setenv PAGER "lv -Ae"

# Change directory color when type 'ls --color'. See man dircolors.
setenv LS_COLORS 'di=01;33;47:'

### end of file

~/.tcshrc

こんな感じです。

### .tcshrc

# Source global definitions
if ( -f /etc/csh.login ) then
source /etc/csh.login
endif

# Source complete definitions
if ( -f $HOME/.complete ) then
source $HOME/.complete
endif

set prompt="%{%}$LOGNAME@%m%B[%W/%D %T]:%b%{%} \!% "
set rprompt="[%{%}%~%{%}]"
set history=5000
set savehist=(5000 merge)

# リダイレクトで上書きする事を許可しない。
set noclobber

# ベルを鳴らさない。
set nobeep

# ^Dでログアウトしない。
set ignoreeof

# ^Iで補完可能な一覧を表示する。(曖昧補完)
set autolist=ambiguous

# 補完の機能を拡張する。
set complete=enhance 

# 補完時にスペルチェックをする。
#set autocorrect

# リターンを押す度にスペルチェックをする。
#set correct=all

# 補完時にヒストリを自動的に展開する。
set autoexpand

# ディレクトリスタックを保存する。
set savedirs

# メッセージカタログを指定する。
#set catalog=ja.ruri2.cat
set catalog=ja.sakura.cat

# メッセージをカラー表示する。
set colorcat

# カレントディレクトリ中にサブディレクトリが
# 見付からなかった場合に cd が検索する
# ディレクトリのリスト
set cdpath=$HOME

# ls をカラー表示する。
#set color

# pushd を引数無しで実行した時に pushd ~ とする。
set pushdtohome

# ディレクトリ名だけで移動できる。
set implicitcd=verbose

# rm * を実行する前に確認する。
set rmstar

# ログインとログアウトを監視する。
set watch = (any any)
# 5分おき
#set watch = (5 any any)

# 10分後に自動的にログアウトする。
#set autologout=10

# 10分おきにメールをチェックする。
#set mail 600 /var/spool/mail/$USER
#set mail 600 $MAIL
# メールをチェックする。
#set mail $MAIL

# Emacs style key binding
bindkey -e

# enable search on prompt
bindkey "^R" i-search-back
bindkey "^S" i-search-fwd

# 補完候補を順に補完する。
bindkey "^[i" complete-word-fwd
bindkey "^[I" complete-word-back

# タイトルバーに現在のディレクトリを表示させる。
if ( $term =~ *term ) then
alias cwdcmd 'echo -n "]2;$cwd"'
endif

# set alias
alias rr rm -rf
alias rm rm -i
alias cp cp -i
alias mv mv -i

alias pd pushd
alias po popd
alias cd "cd \!*; dirs"
alias cl make -f ~/Makefile clean

alias ps ps -fU`whoami` --forest
alias la ls -lhAF --color=auto 

alias xdvi 'xdvi-ja'
alias gs 'gs-ja'

alias mo "mozilla &"
alias e "emacs &"
alias enw "emacs -nw"

alias a ./a.out

alias x exit

alias dpkg "env COLUMNS=130 dpkg"

### end of file

~/.complete

Debain GNU/Linuxについてきたものをそのまま使っています。こんな感じです。